current amplifier with gain control and with self - balancing selection
Vdd  1  2  10V
Vcc  2  0  10V
Vin  7  17 SIN(0V 2V 100k)
Rin  7  17 10k
Vg   18 0  20V
Rv1  7  1  100k
Rv2  17 0  100k
Rout 10 12 100R
****************************************************
*zesilovac 1
M1   4  2  6  0 NFET W=1u L=10u
M2   5  7  6  0 NFET W=1u L=10u
M3   4  4  1  1 PFET W=1u L=5u
M4   5  4  1  1 PFET W=1u L=5u
****************************************************
*zesilovac 2
M11  14 2  6  0 NFET W=1u L=10u
M12  15 17 6  0 NFET W=1u L=10u
M13  14 14 1  1 PFET W=1u L=5u
M14  15 14 1  1 PFET W=1u L=5u
****************************************************
*rizeni zisku
M5   6  1  0  0 NFET W=1u L=20u
M6   1  1  0  0 NFET W=1u L=20u
****************************************************
*vystupni trandy
M7   10 5  0  0 NFET W=10u L=1u
M8   12 15 0  0 NFET W=10u L=1u
M9   1  13 10 1 PFET W=10u L=1u
M10  1  13 12 1 PFET W=10u L=1u
****************************************************
*reference
M15  11 5  0  0 NFET W=10u L=1u
M16  11 15 0  0 NFET W=10u L=1u
M17  1  13 11 1 PFET W=10u L=1u
M18  1  13 11 1 PFET W=10u L=1u
****************************************************
*citlivost-komparator
M19  19 11 21 0 NFE2 W=1u L=1u
M20  13 18 21 0 NFE2 W=1u L=1u
M21  21 1  0  0 NFE2 W=10u L=1u
M22  1  1  0  0 NFE2 W=10u L=1u
M23  1  19 19 1 PFE2 W=1u L=1u
M24  1  19 13 1 PFE2 W=1u L=1u
****************************************************
.model NFET NMOS (KP=4e-5 VTO=3   lambda=0.05)
.model PFET PMOS (KP=4e-5 VTO=-3  lambda=0.05)
.model NFE2 NMOS (KP=4e-5 VTO=0.5 lambda=0.01)
.model PFE2 PMOS (KP=4e-5 VTO=0.5 lambda=0.01)
.control
set maxplots = 1
****************************************************
save @Rin[i]
save @Rout[i]
tran 10nS 25us
****************************************************
settype current @Rin[i]
settype current @Rout[i]
plot  @Rin[i] @Rout[i]
.endc
.end